Перейти на главную страничку сайта (список статей, файлы для скачивания)

ФОРУМ (здесь можно обсудить эту статью, а также любые проблемы программирования на различных макроязыках и в скриптовых средах)

Описание объектов Windows Script Host, их свойств и методов

Объект WshShell

Содержание:

1. Создание объекта 

2. Свойства 

    2.1. CurrentDirectory 

    2.2. Environment 

    2.3. SpecialFolders 

3. Методы 

    3.1. ExpandEnvironmentStrings 

    3.2. Popup 

    3.3. SendKeys 

    3.4. Run 

    3.5. Exec 

    3.6. AppActivate 

    3.7. RegDelete 

    3.8. RegRead 

    3.9. RegWrite 

    3.10. LogEvent 

    3.11. CreateShortcut 

4. Объект WshScriptExec 

    4.1. Создание объекта 

    4.2. Свойства 

        4.2.1. ExitCode 

        4.2.2. ProcessID 

        4.2.3. Status 

        4.2.4. StdOut 

        4.2.5. StdIn 

        4.2.6. StdErr 

    4.3. Методы 

        4.3.1. Terminate 

5. Объект WshShortcut 

    5.1. Создание объекта 

    5.2. Свойства 

        5.2.1. Arguments 

        5.2.2. Description 

        5.2.3. FullName 

        5.2.4. Hotkey 

        5.2.5. IconLocation 

        5.2.6. TargetPath 

        5.2.7. WindowStyle 

        5.2.8. WorkingDirectory 

    5.3. Методы 

        5.3.1. Save 

6. Объект WshUrlShortcut 

    6.1. Создание объекта 

    6.2. Свойства 

        6.2.1. FullName 

        6.2.2. TargetPath 

    6.3. Методы 

        6.3.1. Save  

1. Создание объекта

Пример:

Set WshShell = CreateObject("WScript.Shell") 

2. Свойства

2.1. CurrentDirectory

Синтаксис:

CurrentDirectory 

Возвращаемое значение: строка, путь к текущему каталогу.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

MsgBox WshShell.CurrentDirectory 

2.2. Environment

Синтаксис:

Environment(<Type>) 

Возвращаемое значение: объект-коллекция "WshEnvironment", содержащая переменные среды. Необязательный параметр "Type" - строка, задаёт вид переменных. Возможные значения:

• "System" - переменные среды операционной системы (в Windows NT/2000 - это параметр по умолчанию).
• "User" - переменные среды пользователя.
• "Volatile" - временные переменные.
• "Process" - переменные среды текущего командного окна (в Windows 95/98/Me - это единственно возможный параметр).

Замечание: чтение и запись. В коллекцию можно добавлять элементы и удалять их.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshEnv = WshShell.Environment

MsgBox WshEnv.Item("WINDIR") 

Другой пример:

Set WshShell = CreateObject("WScript.Shell")

WScript.Echo "ПЕРЕМЕННЫЕ System:"

For Each Var In WshShell.Environment("System")

    WScript.Echo Var

Next

WScript.Echo vbCrLf & "ПЕРЕМЕННЫЕ User:"

For Each Var In WshShell.Environment("User")

    WScript.Echo Var

Next

WScript.Echo vbCrLf & "ПЕРЕМЕННЫЕ Volatile:"

For Each Var In WshShell.Environment("Volatile")

    WScript.Echo Var

Next

WScript.Echo vbCrLf & "ПЕРЕМЕННЫЕ Process:"

For Each Var In WshShell.Environment("Process")

    WScript.Echo Var

Next 

2.3. SpecialFolders

Синтаксис:

SpecialFolders(<WshSpecialFolder>) 

Возвращаемое значение: объект-коллекция "SpecialFolders", содержащая пути к специальным папкам Windows. Некоторые специальные папки:

• AllUsersDesktop
• AllUsersStartMenu
• AllUsersPrograms
• AllUsersStartup
• Desktop
• Favorites
• Fonts
• MyDocuments
• NetHood
• PrintHood
• Programs
• Recent
• SendTo
• StartMenu
• Startup
• Template

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set SpecialFolders = WshShell.SpecialFolders

MsgBox SpecialFolders.Item("Desktop")

MsgBox WshShell.SpecialFolders("Desktop") 

Другой пример:

Set WshShell = CreateObject("WScript.Shell")

For Each Folder In WshShell.SpecialFolders

    WScript.Echo Folder

Next 

3. Методы

3.1. ExpandEnvironmentStrings

Синтаксис:

ExpandEnvironmentStrings(<String>) 

Назначение: возвращает значение переменной среды текущего командного окна.

Параметры:

• <String> - строка, имя переменной. Должно быть окружено знаками "%".

Пример:

Set WshShell = CreateObject("WScript.Shell")

MsgBox WshShell.ExpandEnvironmentStrings("%WinDir%") 

3.2. Popup

Синтаксис:

Popup(<Text>,<SecondsToWait>,<Title>,<Type>) 

Назначение: выводит на экран модальное окно сообщения.

Параметры:

• <Text> - строка, текст сообщения.
• <SecondsToWait> - необязательный, число. Количество секунд, по истечении которого окно будет автоматически закрыто.
• <Title> - необязательный, строка. Текст заголовка окна сообщения.
• <Type> - необязательный, число. Комбинация флагов, определяет тип кнопок и значка. Возможные значения флагов:

• 0 - кнопка ОК.
• 1 - кнопки ОК и Отмена.
• 2 - кнопки Стоп, Повтор, Пропустить.
• 3 - кнопки Да, Нет, Отмена.
• 4 - кнопки Да и Нет.
• 5 - кнопки Повтор и Отмена.
• 16 - значок Stop.
• 32 - значок Question.
• 48 - значок Exclamation.
• 64 - значок Information.

Описание: возвращает целое значение, с помощью которого можно узнать, какая кнопка быля нажата пользователем. Возможные значения:

• -1 - таймаут.
• 1 - кнопка ОК.
• 2 - кнопка Отмена.
• 3 - кнопка Стоп.
• 4 - кнопка Повтор.
• 5 - кнопка Пропустить.
• 6 - кнопка Да.
• 7 - кнопка Нет.

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.Popup "Текст сообщения",, "Текст заголовка", 4+16 

3.3. SendKeys

Синтаксис:

SendKeys(<String>) 

Назначение: посылает одно или несколько нажатий клавиш в активное окно (имитация набора на клавиатуре).

Параметры:

• <String> - строка, перечень клавиш в специальном формате.

Описание: каждая клавиша задаётся своим символом. Например, чтобы задать нажатие друг за другом клавиш А, Б и В, нужно указать в качестве параметра строку "АБВ". Некоторые специальные символы следует всегда задавать заключёнными в фигурные скобки. Перечень таких символов:

{+} {^} {%} {~} {(} {)} {[} {]} {{} {}} 

Задание неотображаемых символов и специальных клавиш:

• <Backspace> - {BACKSPACE} или {BS} или {BKSP}
• <Break> - {BREAK}
• <Caps Lock> - {CAPSLOCK}
• <Delete> - {DELETE} или {DEL}
• <End> - {END}
• <Enter> - {ENTER} или ~
• <Esc> - {ESC}
• <Home> - {HOME}
• <Insert> - {INSERT} или {INS}
• <Num Lock> - {NUMLOCK}
• <Page Down> - {PGDN}
• <Page Up> - {PGUP}
• <Print Screen> - {PRTSC}
• <Scroll Lock> - {SCROLLLOCK}
• <Tab> - {TAB}
• <Up Arrow> - {UP}
• <Left Arrow> - {LEFT}
• <Down Arrow> - {DOWN}
• <Right Arrow> - {RIGHT}
• <F1> - {F1}
• <F2> - {F2} и т.д.
• <Shift> - +
• <Ctrl> - ^
• <Alt> - %

Можно использовать скобки. Например, нажатие клавиш <G> и <S> при нажатом <Shift> следует записывать как "+(GS)". Запись "+GS" приведёт к нажатию клавиши <G> при нажатом <Shift>, а затем клавиши <S> уже без <Shift>.

Задание нескольких нажатий: "{LEFT 42}" приведёт к нажатию клавиши <Left Arrow> 42 раза подряд, "{h 10}" приведёт к нажатию клавиши <h> 10 раз подряд.

Метод не может быть использован для посылки нажатий клавиш в приложения MS-DOS.

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.SendKeys "^{ESC}" 

3.4. Run

Синтаксис:

Run(<Command>,<WindowStyle>,<WaitOnReturn>) 

Назначение: создаёт новый независимый процесс, который запускает заданное приложение.

Параметры:

• <Command> - строка, командная строка запуска приложения.
• <WindowStyle> - необязательный, число. Определяет вид окна запускаемого приложения. Некоторые возможные значения:
• 0 - Не отображает окно.
• 1 - Активизирует и отображает окно.
• 2 - Активизирует окно и отображает его в свёрнутом виде.
• 3 - Активизирует окно и отображает его в максимизированном виде.
• <WaitOnReturn> - необязательный, булево (число). True - сценарий возобновит работу только после завершения вызванного процесса. False (по умолчанию) - управление передаётся сразу обратно в сценарий.

Описание: если параметр "WaitOnReturn" установлен в True, метод возвращает код выхода вызванного приложения. Иначе метод всегда возвращает ноль.

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.Run "explorer /e,/root,""C:\Program Files""" 

Другой пример:

Set WshShell = CreateObject("WScript.Shell")

RetCode = WshShell.Run("notepad", 1, True)

MsgBox "Обработка завершена! Код возврата - " & RetCode 

3.5. Exec

Синтаксис:

Exec(<Command>)

Назначение: создаёт новый дочерний процесс (т.е. процесс с теми же переменными среды), который запускает заданное консольное приложение. Возвращается объект "WshScriptExec", который позволяет контролировать ход выполнения запущенного приложения и обеспечивает доступ к потокам StdIn, StdOut и StdErr этого приложения.

Параметры:

• <Command> - строка, командная строка запуска приложения.

Описание: с помощью данного метода можно запускать и графические оконные приложения. В этом случае возвращаемый объект "WshScriptExec" полезен тем, что позволяет получить идентификатор запущенного процесса, который можно использовать, например, для активизации приложения с помощью метода AppActivate.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("nslookup 127.0.0.1")

WScript.Sleep 7000

Set TextStream = WshExec.StdOut

Str = vbNullString

While Not TextStream.AtEndOfStream

    Str = Str & Trim(TextStream.ReadLine()) & vbCrLf

Wend

MsgBox Str 

Другой пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad")

WScript.Sleep 2000

WshShell.AppActivate(WshExec.ProcessID)

WshShell.SendKeys "0123456789" 

3.6. AppActivate

Синтаксис:

AppActivate(<Title>) 

Назначение: активизирует указанное окно какого-либо приложения. Возвращает True в случае успеха и False в случае неудачи.

Параметры:

• <Title> - заголовок окна приложения или идентификатор процесса.

Описание: если в качестве параметра указан заголовок окна приложения, значение параметра сравнивается по очереди с заголовками окон всех запущенных приложений. Если не найдено ни одного точного совпадения, будет производиться поиск окна, заголовок которого начинается с указанной строки. Если и в этом случае не будет найдено ни одного подходящего окна, будет производиться поиск окна, заголовок которого заканчивается на указанную строку. Если будет найдено несколько подходящих окон, произойдёт активизация одного из них (произвольно).

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad")

WScript.Sleep 2000

Res = WshShell.AppActivate(WshExec.ProcessID)

If Res Then WshShell.SendKeys("0123456789") 

3.7. RegDelete

Синтаксис:

RegDelete(<Name>) 

Назначение: удаляет из реестра заданный параметр или раздел целиком.

Параметры:

• <Name> - строка, наименование параметра или раздела.

Описание: если "Name" оканчивается символом "\", метод удаляет ключ целиком, в противном случае удаляется параметр. Параметр "Name" должен начинаться с одного из корневых ключей:

• HKEY_CURRENT_USER - HKCU
• HKEY_LOCAL_MACHINE - HKLM
• HKEY_CLASSES_ROOT - HKCR
• HKEY_USERS - HKEY_USERS
• HKEY_CURRENT_CONFIG - HKEY_CURRENT_CONFIG

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.RegWrite "HKCU\NewKey\","Value"

WshShell.RegWrite "HKEY_CURRENT_USER\NewKey\Param","Value","REG_SZ"

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\Param")

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\")

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\Param"

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\" 

3.8. RegRead

Синтаксис:

RegRead(<Name>) 

Назначение: читает из реестра заданный параметр или значение по умолчанию для раздела.

Параметры:

• <Name> - строка, наименование параметра или раздела.

Описание: если "Name" оканчивается символом "\", метод считывает значение по умолчанию для раздела, в противном случае считывается параметр. Параметр "Name" должен начинаться с одного из корневых ключей:

• HKEY_CURRENT_USER - HKCU
• HKEY_LOCAL_MACHINE - HKLM
• HKEY_CLASSES_ROOT - HKCR
• HKEY_USERS - HKEY_USERS
• HKEY_CURRENT_CONFIG - HKEY_CURRENT_CONFIG

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.RegWrite "HKCU\NewKey\","Value"

WshShell.RegWrite "HKEY_CURRENT_USER\NewKey\Param","Value","REG_SZ"

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\Param")

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\")

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\Param"

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\" 

3.9. RegWrite

Синтаксис:

RegWrite(<Name>,<Value>,<Type>) 

Назначение: записываает в реестр заданный параметр или раздел.

Параметры:

• <Name> - строка, наименование параметра или раздела.
• <Value> - значение параметра или значение для раздела по умолчанию.
• <Type> - необязательный, тип значения. Возможные значения: "REG_SZ", "REG_EXPAND_SZ", "REG_DWORD", "REG_BINARY". Если указано "REG_SZ" или "REG_EXPAND_SZ", параметр "Type" конвертируется в строку, если указано "REG_DWORD", параметр "Type" конвертируется в целое число, если указано "REG_BINARY", параметр "Type" должен быть целым числом.

Описание: если "Name" оканчивается символом "\", метод записывает раздел, в противном случае записывается параметр. Параметр "Name" должен начинаться с одного из корневых ключей:

• HKEY_CURRENT_USER - HKCU
• HKEY_LOCAL_MACHINE - HKLM
• HKEY_CLASSES_ROOT - HKCR
• HKEY_USERS - HKEY_USERS
• HKEY_CURRENT_CONFIG - HKEY_CURRENT_CONFIG

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.RegWrite "HKCU\NewKey\","Value"

WshShell.RegWrite "HKEY_CURRENT_USER\NewKey\Param","Value","REG_SZ"

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\Param")

MsgBox WshShell.RegRead("HKEY_CURRENT_USER\NewKey\")

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\Param"

WshShell.RegDelete "HKEY_CURRENT_USER\NewKey\" 

3.10. LogEvent

Синтаксис:

LogEvent(<Type>,<Message>,<Target>) 

Назначение: протоколирует событие в журнале WindowsNT или в файле WSH.log. Возвращает True в случае успеха и False в противном случае.

Параметры:

• <Type> - число, тип сообщения. Возможные значения:
• 0 - SUCCESS
• 1 - ERROR
• 2 - WARNING
• 4 - INFORMATION
• 8 - AUDIT_SUCCESS
• 16 - AUDIT_FAILURE
• <Message> - строка, текст сообщения.
• <Target> - строка, название системы, в которой протоколируется событие (по умолчанию - локальная система), может задаваться только в Windows NT/2000/XP.

Описание: в Windows NT/200/XP события записываются в системном журнале, а в Windows 9x - в файле WSH.log, который находится в каталоге пользователей.

Пример:

Set WshShell = CreateObject("WScript.Shell")

WshShell.LogEvent 4, "Test event!" 

3.11. CreateShortcut

Синтаксис:

CreateShortcut(<Path>) 

Назначение: возвращает объект "WshShortcut" или "WshURLShortcut", указывающий на ярлык .lnk или .url.

Параметры:

• <Path> - строка, полный путь к создаваемому или изменяемому файлу ярлыка.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshURLShortcut = WshShell.CreateShortcut("C:\Microsoft.url")

WshURLShortcut.TargetPath = "http://microsoft.com"

WshURLShortcut.Save 

4. Объект WshScriptExec

4.1. Создание объекта

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad") 

4.2. Свойства

4.2.1. ExitCode

Синтаксис:

ExitCode 

Возвращаемое значение: код выхода, устанавливаемый дочерней задачей при завершении выполнения.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

'запуск "xcopy" с заведомо ошибочными параметрами

Set WshExec = WshShell.Exec("xcopy abc123")

'пауза для запуска приложения

WScript.Sleep 2000

'чтение кода выхода

MsgBox WshExec.ExitCode 

4.2.2. ProcessID

Синтаксис:

ProcessID 

Возвращаемое значение: идентификатор запущенного процесса (PID).

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad")

WScript.Sleep 2000

WshShell.AppActivate WshExec.ProcessID

WshShell.SendKeys "0123456789" 

4.2.3. Status

Синтаксис:

Status 

Возвращаемое значение: состояние запущенного процесса. Возможные значения:

• 0 - приложение запущено.
• 1 - приложение завершено.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad")

WScript.Sleep 2000

MsgBox "status - " & WshExec.Status

WshExec.Terminate

WScript.Sleep 2000

MsgBox "status - " & WshExec.Status 

4.2.4. StdOut

Синтаксис:

StdOut 

Возвращаемое значение: объект "TextStream", соответствующий стандартному выходному потоку запущенной задачи.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("nslookup")

Set InStream = WshExec.StdIn

InStream.WriteLine "help"

InStream.WriteLine "exit"

Set OutStream = WshExec.StdOut

Str = vbNullString

While Not OutStream.AtEndOfStream

    Str = Str & Trim(OutStream.ReadLine()) & vbCrLf

Wend

MsgBox Str 

4.2.5. StdIn

Синтаксис:

StdIn 

Возвращаемое значение: объект "TextStream", соответствующий стандартному входному потоку запущенной задачи.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("nslookup")

Set InStream = WshExec.StdIn

InStream.WriteLine "help"

InStream.WriteLine "exit"

Set OutStream = WshExec.StdOut

Str = vbNullString

While Not OutStream.AtEndOfStream

    Str = Str & Trim(OutStream.ReadLine()) & vbCrLf

Wend

MsgBox Str 

4.2.6. StdErr

Синтаксис:

StdErr 

Возвращаемое значение: объект "TextStream", соответствующий стандартному потоку ошибок запущенной задачи.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("nslookup")

Set InStream = WshExec.StdIn

InStream.WriteLine "abc123"

InStream.WriteLine "exit"

Set OutStream = WshExec.StdErr

Str = vbNullString

While Not OutStream.AtEndOfStream

    Str = Str & Trim(OutStream.ReadLine()) & vbCrLf

Wend

MsgBox Str 

4.3. Методы

4.3.1. Terminate

Синтаксис:

Terminate 

Назначение: пытается закрыть приложение, посылая ему сообщение WM_CLOSE. Если это не срабатывает, задача завершается принудительно.

Параметры: нет.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshExec = WshShell.Exec("notepad")

WScript.Sleep 2000

MsgBox "status - " & WshExec.Status

WshExec.Terminate

WScript.Sleep 2000

MsgBox "status - " & WshExec.Status 

5. Объект WshShortcut

5.1. Создание объекта

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk") 

5.2. Свойства

5.2.1. Arguments

Синтаксис:

Arguments 

Возвращаемое значение: строка, параметры командной строки программы, запускаемой ярлыком.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.2. Description

Синтаксис:

Description 

Возвращаемое значение: строка, описание в поле "Комментарий" ("Comment") в свойствах ярлыка.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.3. FullName

Синтаксис:

FullName 

Возвращаемое значение: строка, полный путь к файлу ярлыка.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.4. Hotkey

Синтаксис:

Hotkey 

Возвращаемое значение: строка, содержащая названия горячих клавиш, разделённые знаком "+".

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.5. IconLocation

Синтаксис:

IconLocation 

Возвращаемое значение: строка, содержащая расположение иконки для ярлыка в формате "путь к файлу, индекс иконки". Индексы иконок начинаются с нуля.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.6. TargetPath

Синтаксис:

TargetPath 

Возвращаемое значение: строка, содержащая путь к исполняемому файлу.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.7. WindowStyle

Синтаксис:

WindowStyle 

Возвращаемое значение: число, определяющее вид окна запускаемого приложения. Возможные значения:

• 1 - Стандартное окно.
• 3 - Максимизированное окно.
• 7 - Минимизированное окно.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.2.8. WorkingDirectory

Синтаксис:

WorkingDirectory 

Возвращаемое значение: строка, путь к рабочему каталогу ярлыка.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

5.3. Методы

5.3.1. Save

Синтаксис:

Save 

Назначение: сохраняет ярлык.

Параметры: нет.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshShortcut = WshShell.CreateShortcut("C:\Notepad.lnk")

WshShortcut.Arguments = "C:\autoexec.bat"

WshShortcut.Description = "Пробный ярлык"

WshShortcut.HotKey = "CTRL+ALT+F"

WshShortcut.IconLocation = "shell32.dll, 5"

WshShortcut.TargetPath = "notepad.exe"

WshShortcut.WindowStyle = 1

WshShortcut.WorkingDirectory = "C:\"

MsgBox WshShortcut.FullName

WshShortcut.Save 

6. Объект WshUrlShortcut

6.1. Создание объекта

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshUrlShortcut = WshShell.CreateShortcut("C:\Microsoft.url") 

6.2. Свойства

6.2.1. FullName

Синтаксис:

FullName 

Возвращаемое значение: строка, полный путь к файлу ярлыка.

Замечание: только чтение.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshUrlShortcut = WshShell.CreateShortcut("C:\Microsoft.url")

WshUrlShortcut.TargetPath = "http://microsoft.com"

MsgBox WshUrlShortcut.FullName

WshUrlShortcut.Save 

6.2.2. TargetPath

Синтаксис:

TargetPath 

Возвращаемое значение: строка, содержащая путь к документу Интернет.

Замечание: чтение и запись.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshUrlShortcut = WshShell.CreateShortcut("C:\Microsoft.url")

WshUrlShortcut.TargetPath = "http://microsoft.com"

MsgBox WshUrlShortcut.FullName

WshUrlShortcut.Save 

6.3. Методы

6.3.1. Save

Синтаксис:

Save 

Назначение: сохраняет ярлык.

Параметры: нет.

Пример:

Set WshShell = CreateObject("WScript.Shell")

Set WshUrlShortcut = WshShell.CreateShortcut("C:\Microsoft.url")

WshUrlShortcut.TargetPath = "http://microsoft.com"

MsgBox WshUrlShortcut.FullName

WshUrlShortcut.Save 

Составление - Людоговский Александр

Перейти на главную страничку сайта (список статей, файлы для скачивания)

© 2007 http://www.script-coding.com При любом использовании материалов сайта обязательна ссылка на него как на источник информации, а также сохранение целостности и авторства материалов.