Блокировка настроек Internet Explorer
Код (DOS):
@Echo Off
:: Этот командный файл ограничивает политиками управление домашней страницей, поиском и надстройками в IE
:: Автор: Вадим Стеркин. Подробнее http://www.outsidethebox.ms/12904/
:: Политика "Отключить изменение параметров домашней страницы"
:: Задает домашнюю страницу и фиксирует ее политикой
REG ADD "HKEY_CURRENT_USER\Software\Policies\Microsoft\Internet Explorer\Main" /v "Start Page" /d "http://www.outsidethebox.ms/" /f
REG ADD "HKEY_CURRENT_USER\Software\Policies\Microsoft\Internet Explorer\Control Panel" /v HomePage /t REG_DWORD /d 1 /f
:: Политика "Разрешить сторонние расширения браузера"
:: Запрещает запуск BHO, блокируя панели браузера
REG ADD "HKEY_CURRENT_USER\Software\Policies\Microsoft\Internet Explorer\Main" /v "Enable Browser Extensions" /t REG_SZ /d no /f
:: Политика "Не разрешать пользователям включать и отключать надстройки"
:: Полностью отключает управление надстройками
:: REG ADD "HKEY_CURRENT_USER\Software\Policies\Microsoft\Internet Explorer\Restrictions" /v NoExtensionManagement /t REG_DWORD /d 1 /f
:: Политика "Ограничить поставщиков служб поиска заданным списком поставщиков"
:: Включает ограничение списка поисков
REG ADD "HKEY_CURRENT_USER\Software\Policies\Microsoft\Internet Explorer\Infodelivery\Restrictions" /v UsePolicySearchProvidersOnly /t REG_DWORD /d 1 /f
:: Переносит текущий список поисков в политики
REG EXPORT "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\SearchScopes" "%temp%\scopes.reg"
CALL :SearchScope
REG IMPORT "%temp%\scopes.reg"
DEL "%temp%\scopes.reg"
EXIT
:SearchScope
:: http://forum.oszone.net/thread-191684.html
Set Source=%temp%
SetLocal EnableDelayedExpansion
For %%A In ("%Source%\scopes.reg") Do (
For /F "Tokens=1* Delims=:" %%B In ('Type "%%A"^|Findstr /IN "$"') Do (
Set Str=%%C
If "!Str!"=="" (
Echo .>>"%%A_tmp"
) Else (
Set Str=!Str:Software\=Software\Policies\!
Echo !Str!>>"%%A_tmp"
)
)
Move /Y "%%A_tmp" "%%~fA"
)
EndLocal
