Сборник формул для условного форматирования

В данной статье собран список формул, которые можно использовать в условном форматировании ячеек, заданным при помощи формулы:

• Excel 2003: Формат(Format)-Условное форматирование(Conditional formatting)- формула;
• Excel 2007-2010: вкладка Главная(Home)-Условное форматирование(Conditional formatting)-Создать правило(New rule)-Использовать формулу для определения форматируемых ячеек(Use a formula to determine which cells to format)

Подробнее об условном форматировании можно прочитать в статье: Основные понятия условного форматирования и как его создать

Все условия приведены для диапазона A1:A20. Это означает, что для корректного выполнения условия необходимо выделить диапазон A1:A20(столбцов может быть больше), начиная с ячейки A1, после чего назначить условие.
Если выделять необходимо не с первой строки, а скажем, с 4-ой, то и выделить надо будет диапазон A4:A20 и в формуле для условия указывать в качестве критерия первую ячейку выделенного диапазона - A4.

Если необходимо выделять форматированием не только конкретную ячейку, удовлетворяющую условию, а всю строку таблицы на основе ячейки одного столбца, то перед установкой правила необходимо выделить всю таблицу, строки которой необходимо форматировать, а ссылку на столбец с критерием закрепить:
=$A1=МАКС($A$1:$A$20)
при выделенном диапазоне A1:F20(диапазон применения условного форматирования), будет выделена строка A7:F7, если в ячейке A7 будет максимальное число.

Так же можно применять не к конкретно одному столбцу, а к полностью диапазону. Но в этом случае надо знать принцип смещения ссылок в формулах, чтобы условия применялись именно к нужным ячейкам. Например, если задать условие для диапазона B1:D10 в виде формулы: =B1<A1, то цветом будут выделены ячейки столбца B, если значение ячейки столбца А в той же строке меньше(B1<A1, B3<A3). При этом если ячейки столбца D меньше ячеек столбца C в той же строке - они тоже будут выделены(D1<C1, D5<C5).

ЧИСЛОВЫЕ ЗНАЧЕНИЯ

1. Выделение ячеек с числами:
   =ЕЧИСЛО(A1)
2. Выделение ячеек с числами, но не учитывая нули:
   =И(ЕЧИСЛО(A1);A1<>0)
3. Выделение строк со значением больше 0:
   =A1>0
4. Выделение строк со значением в диапазоне от 3 до 10:
   =И(A1>=3;A1<=10)
5. Выделение в диапазоне $A$1:$A$20 ячейки с максимальным значением:
   =A1=МАКС($A$1:$A$20)
6. Выделение в диапазоне $A$1:$A$20 ячейки с минимальным значением:
   =И(ЕЧИСЛО(A1);A1=МИН($A$1:$A$20))
7. Выделение в диапазоне $A$1:$A$20 ячейки со вторым по величине числом. Т.е. из чисел 1,2,3,4,5,6,7 будет выделено число 6:
   =A1=НАИБОЛЬШИЙ($A$1:$A$20;2)

 
ТЕКСТОВЫЕ ЗНАЧЕНИЯ

8. Выделение ячеек с любым текстом:
   =ЕТЕКСТ(A1)
9. Выделение ячеек с текстом Итог:
   =A1="Итог"
10. Выделение ячеек, содержащих текст Итог:
    =СЧЁТЕСЛИ(A1;"*итог*")
    =НЕ(ЕОШ(ПОИСК("итог";A1)))
11. Выделение ячеек, не содержащих текст Итог:
    =СЧЁТЕСЛИ(A1;"*итог*")=0
    =ЕОШ(ПОИСК("итог";A1))
12. Выделение ячеек, текст которых начинается со слова Итог:
    =ЛЕВСИМВ(A1;4)="Итог"
13. Выделение ячеек, текст которых заканчивается на слово Итог:
    =ПРАВСИМВ(A1;4)="Итог"

 
ДАТА / ВРЕМЯ

14. Выделение текущей даты:
    =A1=СЕГОДНЯ()
15. Выделение ячейки с датой, больше текущей:
    =A1>СЕГОДНЯ()
16. Выделение ячейки с датой, которая наступит через неделю:
    =A1=СЕГОДНЯ()+7
17. Выделение ячеек с датами текущего месяца(любого года):
    =МЕСЯЦ(A1)=МЕСЯЦ(СЕГОДНЯ())
18. Выделение ячеек с датами текущего месяца текущего года:
    =И(МЕСЯЦ(A1)=МЕСЯЦ(СЕГОДНЯ());ГОД(A1)=ГОД(СЕГОДНЯ()))
    или
    =ТЕКСТ(A1;"ГГГГММ")=ТЕКСТ(СЕГОДНЯ();"ГГГГММ")
19. Выделение ячеек с выходными днями:
    =ДЕНЬНЕД(A1;2)>5
20. Выделение ячеек с будними днями:
    =ДЕНЬНЕД(A1;2)<6
21. Выделение ячеек, входящих в указанный период(промежуток) дат:
    =И($A1>ДАТА(2015;9;1);$A1<ДАТА(2015;10;1))

 
ДРУГИЕ

22. Выделение различий в ячейках по условию:
    =A1<>$B1
23. Выделение ячейки, если ячейка следующего столбца(B) этой же строки меньше:
    =A1>B1
24. Выделение строк цветом через одну:
    =ОСТАТ(СТРОКА();2)
25. Выделение строк цветом, если значение ячейки столбца A присутствует в диапазоне $F$1:$H$5000:
    =СЧЁТЕСЛИ($F$1:$H$5000;A1)
26. Выделение строк цветом, если значение ячейки столбца A отсутствует в диапазоне $F$1:$H$5000:
    =СЧЁТЕСЛИ($F$1:$H$5000;A1)=0
27. Выделение цветом ячейки, если её значение в диапазоне A1:A20 второе по счету:
    =СЧЁТЕСЛИ($A$1:$A1;A1 )=2
28. Выделение ячеек, содержащих ошибки (#ЗНАЧ!; #Н/Д; #ССЫЛКА! и т.п.). Помимо просто выявления ячеек с ошибками можно применять, когда необходимо скрыть ошибочные значения в ячейках(назначив цвет шрифта таким же, как и цвет заливки):
    =ЕОШИБКА(A)
29. Выделение непустых ячеек в столбце A:
    =$A1<>""