Введение в объектную модель FSO
Новая особенность для VB6 - модель объекта ( FSO ) Объектная Файловая Система, которая обеспечивает основанный на объектах инструмент для работы с папками и файлами.
Это позволяет Вам использовать знакомый синтаксис object.method с богатым набором свойств, методов, и событий, чтобы обработать папки и файлы, в дополнение к использованию традиционных методов и команд Visual Basic. Объектная модель FSO дает вашим прикладным программам способность создавать, изменять, перемещать, и удалить папки, или выяснять, если специфические папки существуют, и если так, то где. Это также дает возможность Вам получить информацию относительно папок, типа их имен, дат, когда они были созданы или в последний раз изменялись, и т.д.
Объектная модель FSO позволяет намного проще проводить обработку файлов. При обработке файлов, ваша основная цель состоит в том, чтобы сохранить данные в области - и ресурсо-эффективном, легко доступном формате. Вы сможете создавать файлы, вставлять и изменять(заменять) и выводить (считывать) данные.
Объектная модель FSO, которая содержится в библиотеке типов Scripting type library (Scrrun.Dll), поддерживает создание текстового файла и манипулирование им
через объект TextStream. Однако это не поддерживает создание или манипулирование двоичными файлами. Чтобы управлять двоичными файлами, используется команда Open с бинарным флагом.
Объекты Файловой системы
Объектная модель FSO имеет следующие объекты:
Drive(Дисковод) - Позволяет Вам получить информацию относительно дисководов присоединенных к системе, их типа, количества доступного участка памяти, их обозначения, и т.д. Обратите внимание, что "дисковод" не обязательно жесткий диск. Это может быть дисковод CD-ROM, вертуальный диск, и т.д. Также не обязательно, чтобы дисководы были физически присоединенными к системе; они могут быть также логически подсоединены через локальную сеть.
Folder(Папка) - Позволяет Вам создавать, удалять, или перемещать папки, плюс запрос системы относительно их имен, путей, и так далее.
Files(Файлы) - Позволяет Вам создавать, удалять, или перемещать файлы, плюс запрос системы относительно их имен, путей, и так далее.
FileSystemObject - Основной объект группы, с полными методами, которые позволят Вам создать, удалять, получать информацию обовсем, и вообще, управляет дисководами, папками, и файлами. Многие из методов, связанных с этим объектом дублированы в других объектах.
TextStream - Дает возможность Вам читать и писать текстовые файлы.
Программирование в Объектной Модели FSO
Программирование в Объектной Модели FSO включает три основных задачи:
1. Использование метода CreateObject или объявления переменной как объект FileSystemObject, для создания объекта FileSystemObject;
2. Использование соответствующего метода в недавно созданном объекте;
3. Вызов свойств объекта.
Объектная Модель FSO содержится в библиотеке типов, называемой Scripting, которая размещена в файле Scrrun.Dll . Если Вы пока не имеете ссылку, то поставьте ее в меню References| Microsoft Scripting Runtime. Вы можете затем использовать Object Browser, чтобы просмотреть объекты, свойства, методы и события, а также константы.
Создание объекта FileSystemObject
Первый шаг должен создать объект FileSystemObject, чтобы работать с ним. Вы можете сделать это двумя способами: Объявить переменную, как объект:
Код (vb.net):
Dim fso As New FileSystemObject
Используя метод CreateObject создать объект FileSystemObject:
Код (vb.net):
Set fso = CreateObject ("Scripting.FileSystemObject")
Обратите внимание, что первый метод работает только в Visual Basic, в то время, как второй метод работает и в Visual Basic и в VBScript.
Использование соответствующих методов
Следующий шаг должен использовать соответствующий метод объекта FileSystemObject.
Например, если Вы хотите создавать новый объект, Вы можете использовать или CreateFolder или CreateTextFile. (Модель объекта FSO не поддерживает создание или стирание дисководов.).
Если Вы хотите удалить объекты, Вы можете использовать методы DeleteFile или DeleteFolder объекта FileSystemObject, или метод Delete объектов File или Folder.
При использовании соответствующих методов, Вы можете также копировать и перемещать файлы и папки.
Обратите внимание, что некоторые функциональные возможности в модели объекта FileSystemObject избыточны. Например, Вы можете копировать файл, использующий или метод CopyFile объекта FileSystemObject, или Вы можете использовать метод Copy объекта File. Методы работают также. И существуют, чтобы дать Вам максимум гибкости программирования.
Вызов, существующих Drives (Дисководов) , Files (Файлов) и Folders (Папок)
Чтобы получить доступ к существующему дисководу, файлу или папке, используется соответствующий метод "Get" объекта FileSystemObject:
- GetDrive;
- GetFolder;
- GetFile;
Например:
Код (vb.net):
Dim fso As New FileSystemObject, fil As File
Set fil = fso.GetFile("c:\test.txt")
Обратите внимание, однако, что Вы не должны использовать методы "Get" для недавно созданных объектов, так как функции "Get" уже возвращает программе обработки недавно созданный объект.
Например, если Вы создаете новую папку, используя метод CreateFolder, Вы затем не должны использовать метод GetFolder, чтобы обратиться к свойствам, типа Name, Path, Size и т.д.
Только объявите переменную функции CreateFolder, чтобы получить программу обработки недавно созданной папке, затем обратитесь к свойствам, методам, и событиям:
Код (vb.net):
Private Sub Create_Folder()
Dim fso As New FileSystemObject, fldr As Folder
Set fldr = fso.CreateFolder("C:\MyTest")
MsgBox "Created folder: " & fldr.Name
End Sub
Обращение к Properties (Свойствам) Объекта
Как только Вы имеете код обработки объекта, Вы можете обращаться к его свойствам.
Например, если Вы хотите получить имя специфической папки. Сначала Вы создаете образец объекта, затем Вы получаете код для его обработки соответствующим методом (в этом случае метод GetFolder, так как папка уже существует):
Код (vb.net):
Set fldr = fso.GetFolder("c:\")
Теперь, когда Вы имеете код обработки объекта Folder, Вы можете проверить свойство Name:
Код (vb.net):
Debug.Print "Folder name is: "; fldr.Name
Если Вы хотите выяснять когда в последний раз, файл изменялся, используется следующий синтаксис:
Код (vb.net):
Dim fso As New FileSystemObject, fil As File
'Получаем объект File, чтобы сделать запрос
Set fil = fso.GetFile ( "C:\detlog.txt" )
'Печатаем информацию
msgbox "File last modified: " & fil.DateLastModified
Работа с Drives (Дисководами) и Folders (Папками)
Объектная модель FSO может программно работать с дисководами и папками, точно так, как Вы с Windows Explorer в интерактивном режиме. Вы можете копировать и перемещать папки, получать информацию относительно дисководов и папок, и т.д.
Получение информации относительно Drives (Дисководов) Объект Drive позволяет Вам получать информацию относительно различных дисководов, присоединенных к системе или физически или через сеть.
Свойства позволяют Вам получить информацию относительно:
- Полный размера дисковода в байтах (свойство TotalSize);
- Количество доступного свободного места на дисководе в байтах (свойства AvailableSpace или FreeSpace);
- Буквенного обозначения дисковода (свойство DriveLetter);
- Какого типа дисковод, сменный, фиксированный, сетевой, CD-ROM или RAM (свойство DriveType);
- Серийный номер дисковода (свойство SerialNumber);
- Тип файловой системы использования дисковода FAT, FAT32, NTFS, и т.д (свойство FileSystem);
- Является ли дисковод доступен для использования (свойство IsReady);
- Имя общих и/или Имя объемa (свойства ShareName и VolumeName);
- Путь или корневую папку дисковода (свойства Path и RootFolder);
Пример использования объекта Drive (Дисковода)
Пример ниже показывается, как использовать объект Drive, чтобы получить полную информацию относительно дисковода.
Не забудьте, что в следующем коде Вы не будете видеть ссылку к фактическому объекту Drive, достаточно, что Вы используете метод GetDrive чтобы получить ссылку для существующего объекта Drive (в этом случае - drv):
Код (vb.net):
Private Sub Command3_Click()
Dim fso As New FileSystemObject, drv As Drive, s As String
Set drv = fso.GetDrive(fso.GetDriveName("c:"))
s = "Drive " & UCase("c:") & " - "
s = s & drv.VolumeName & vbCrLf
s = s & "Total Space: " & FormatNumber(drv.TotalSize / 1024, 0)
s = s & " Kb" & vbCrLf
s = s & "Free Space: " & FormatNumber(drv.FreeSpace / 1024, 0)
s = s & " Kb" & vbCrLf
MsgBox s
End Sub
Работа с Folders (Папками)
Этот список показывает общие задачи папки и методы для выполнения их:
- Создать папку - FileSystemObject.CreateFolder
- Удалить папку - Folder.Delete или FileSystemObject.DeleteFolder
- Переместить папку - Folder.Move или FileSystemObject.MoveFolder
- Копировать папку - Folder.Copy или FileSystemObject.CopyFolder
- Возвратить имя папки - Folder.Name
- Выяснить, существует ли папка на дисководе - FileSystemObject.FolderExists
- Получить образец существующего объекта - Folder FileSystemObject.GetFolder
- Выяснить имя папки, родителя папки - FileSystemObject.GetParentFolderName
- Выяснить путь системных папок - FileSystemObject.GetSpecialFolder
Этот пример показывает использование объектов Folder и FileSystemObject, чтобы управлять папками и получать информацию о них:
Код (vb.net):
Private Sub Command10_Click()
'Получаем образец
FileSystemObject Dim fso As New FileSystemObject, fldr As Folder, s As String
' Объект
Get Drive Set fldr = fso.GetFolder("c:")
' Печатаем родительское имя папки
Debug.Print "Parent folder name is: " & fldr
' Печатаем имя дисковода
Debug.Print "Contained on drive " & fldr.Drive
' Печатаем имя корневой папки
If fldr.IsRootFolder = True Then
Debug.Print "This folder is a root folder."
Else
Debug.Print "This folder isn't a root folder."
End If
' Создаем новую папку объектом FileSystemObject
fso.CreateFolder ("c:\Bogus")
Debug.Print "Created folder C:\Bogus"
' Печатаем основное имя папки
Debug.Print "Basename = " & fso.GetBaseName("c:\bogus")
' Удаляем недавно созданную папку
fso.DeleteFolder ("c:\Bogus")
Debug.Print "Deleted folder C:\Bogus"
End Sub
Работа с Files (Файлами)
Вы можете работать с файлами в Visual Basic, используя новые объектно-ориентированные объекты FSO типа Copy, Delete, Move и OpenAsTextStream, так же, как и более старые существующие функции типа Open, Close, FileCopy, GetAttr, и т.д. Обратите внимание, что Вы можете перемещать, копировать или удалять файлы независимо от типа файла. Имеются две главных категории манипулирования файлами:
Создание, добавление или удаления данных, или чтение файлов;
Перемещение, копирование и удаление файлов;
Создание файлов и добавления данных с помощью File System Objects
Имеются три способа создать последовательный текстовый файл (иногда упоминаемый как "текстовый поток"). Один путь состоит в том, чтобы использовать метод CreateTextFile. Создаем пустой текстовый файл:
Код (vb.net):
Dim fso As New FileSystemObject, fil As File
Set fil = fso.CreateTextFile("c:\testfile.txt", True)
Обратите внимание, что модель объекта FSO еще не поддерживает создание произвольных (random) или двоичных (binary) файлов.
Другой путь состоит в том, чтобы использовать метод OpenTextFile объекта FileSystemObject с установкой флага ForWriting:
Код (vb.net):
Dim fso As New FileSystemObject, ts As New TextStream
Set ts = fso.OpenTextFile("c:\test.txt", ForWriting)
Или Вы можете использовать метод OpenAsTextStream с установкой флага ForWriting:
Код (vb.net):
Dim fso As New FileSystemObject, fil As File, ts As TextStream
Set fso = CreateObject("Scripting.FileSystemObject")
fso.CreateTextFile ("test1.txt")
Set fil = fso.GetFile("test1.txt")
Set ts = fil.OpenAsTextStream(ForWriting)
Добавление данных к файлу
Как только текстовый файл создан, Вы можете добавлять данные. Для этого необходимо:
- Открыть текстовый файл для записи данных.
- Записать данные.
- Закрыть файл.
Чтобы открыть файл, Вы можете использовать любой из двух методов:
- метод OpenAsTextStream объекта File или
- метод OpenTextFile объекта FileSystemObject.
Чтобы записать данные в открытый текстовый файл, используйте методы Write или WriteLine объекта TextStream.
Единственое различие между Write и WriteLine - то, что WriteLine добавляет символы newline к концу строки. Если Вы хотите добавлять newline к текстовому файлу, используйте метод WriteBlankLines.
Чтобы закрыть открытый файл, используйте метод Close объекта TextStream.
Код (vb.net):
Sub Create_File()
Dim fso, txtfile
Set fso = CreateObject("Scripting.FileSystemObject")
Set txtfile = fso.CreateTextFile("c:\testfile.txt", True)
'Запись линии
txtfile.Write ("This is a test. ")
'Запись линии с символом newline
txtfile.WriteLine("Testing 1, 2, 3.")
'Запись трех символов newline в файл
txtfile.WriteBlankLines(3)
txtfile.Close
End Sub
Чтение файлов File System Objects
Чтобы читать данные из текстового файла, используйте методы Read, ReadLine или ReadAll объекта TextStream:
- Чтение определенного числа символов из файла - Read
- Чтение всей линии (но не, включая, символ newline) - ReadLine
- Чтение всего содержания текстового файла - ReadAll
Если Вы используете метод Read или ReadLine, и Вы хотите перейти к специфической части данных.
Вы можете использовать метод Skip или SkipLine. Полученный в результате использования этих методов текст может быть сохранен в символьной переменной и анализироваться Left, Right и Mid.
Обратите внимание, что константа vbNewLine содержит символ или символы (в зависимости от операционной системы) чтобы продвинуть курсор к началу следующей линии (возврат каретки). Знайте, что концы некоторых символьных переменных могут иметь такие непечатаемые символы.
Код (vb.net):
Sub Read_Files()
Dim fso As New FileSystemObject, txtfile
Dim fil1 As File, ts As TextStream
Set txtfile = fso.CreateTextFile("c:\testfile.txt", True)
MsgBox "Writing file"
' Запись линии
Set fil1 = fso.GetFile("c:\testfile.txt")
Set ts = fil1.OpenAsTextStream(ForWriting)
ts.Write "Hello World"
ts.Close
' Чтение содержания файла
Set ts = fil1.OpenAsTextStream(ForReading)
s = ts.ReadLine
MsgBox s
ts.Close
End Sub
Перемещение, копирование и удаление файлов
Модель объекта FSO имеет два метода для перемещения, копирования и удаления файлов:
- Переместите файл - File.Move or FileSystemObject.MoveFile
- Копируйте файл - File.Copy or FileSystemObject.CopyFile
- Удалите файл - File.Delete or FileSystemObject.DeleteFile
Этот пример:
- создает текстовый файл в корневой директории дисковода C,
- пишет некоторую информацию в нем,
- перемещает его в каталог, называемый \tmp,
- делает копию его в каталог, называемый \temp, затем
- удаляет копии из обоих каталогов.
Чтобы выполнять этот пример, удостоверитесь, что Вы имеете каталоги, именованные \tmp и \temp в корневой директории дисковода C.
Код (vb.net):
Sub Manip_Files()
Dim fso As New FileSystemObject, txtfile, fil1, fil2
Set txtfile = fso.CreateTextFile("c:\testfile.txt", True)
MsgBox "Writing file"
txtfile.Write ("This is a test.")
txtfile.Close
MsgBox "Moving file to c:\tmp"
' Код обработки файла в корне C:\
Set fil1 = fso.GetFile("c:\testfile.txt")
' Перемещаем файл в директорию \tmp
fil1.Move ("c:\tmp\testfile.txt")
MsgBox " Копируем файл в c:\temp"
' Копируем файл в \temp
fil1.Copy ("c:\temp\testfile.txt")
MsgBox "Удаляем файлы"
' Код получения текущих дерикторий файлов
Set fil1 = fso.GetFile("c:\tmp\testfile.txt")
Set fil2 = fso.GetFile("c:\temp\testfile.txt")
' Удаляем дайлы fil1.Delete
fil2.Delete
MsgBox "Все!"
End Sub
Источник
Dragokas , 26 янв 2014 в 18:49
