MyTetra Share
Делитесь знаниями!
Функция ТЕКСТ
Время создания: 16.03.2019 23:22
Текстовые метки: формулы, ТЕКСТ
Раздел: !Закладки - MSO - Excel
Запись: xintrea/mytetra_db_adgaver_new/master/base/1516353511qcfgxz8b2n/text.html на raw.githubusercontent.com

Функция ТЕКСТ

Авторы:

С помощью функции ТЕКСТ можно изменить представление числа, применив к нему форматирование с кодами форматов. Это полезно в ситуации, когда нужно отобразить числа в удобочитаемом виде либо объединить их с текстом или символами.

Примечание : Функция ТЕКСТ преобразует числа в текст, что может затруднить их использование в дальнейших вычислениях. Рекомендуем сохранить исходное значение в одной ячейке, а функцию ТЕКСТ использовать в другой. Затем, если потребуется создать другие формулы, всегда ссылайтесь на исходное значение, а не на результат функции ТЕКСТ.

Технические сведения

Синтаксис

ТЕКСТ(значение; формат)

Аргументы функции ТЕКСТ описаны ниже.

Имя аргумента

Описание

значение

Числовое значение, которое нужно преобразовать в текст.

формат

Текстовая строка, определяющая формат, который требуется применить к указанному значению.

Общие сведения

Самая простая функция ТЕКСТ означает следующее:

  • =ТЕКСТ(значение, которое нужно отформатировать; "код формата, который требуется применить")

Ниже приведены популярные примеры, которые вы можете скопировать прямо в Excel, чтобы поэкспериментировать самостоятельно. Обратите внимание: коды форматов заключены в кавычки.

Формула

Описание

=ТЕКСТ(1234,567;"# ##0,00 ₽")

Денежный формат с разделителем групп разрядов и двумя разрядами дробной части, например: 1 234,57 ₽. Обратите внимание: Excel округляет значение до двух разрядов дробной части.

=ТЕКСТ(СЕГОДНЯ();"ДД.ММ.ГГ")

Сегодняшняя дата в формате ДД/ММ/ГГ, например: 14.03.12

=ТЕКСТ(СЕГОДНЯ();"ДДДД")

Сегодняшний день недели, например: понедельник

=ТЕКСТ(ТДАТА();"ЧЧ:ММ")

Текущее время, например: 13:29

=ТЕКСТ(0,285;"0,0 %")

Процентный формат, например: 28,5 %

=ТЕКСТ(4,34; "# ?/?")

Дробный формат, например: 4 1/3

=СЖПРОБЕЛЫ(ТЕКСТ(0,34;"# ?/?"))

Дробный формат, например: 1/3 Обратите внимание: функция СЖПРОБЕЛЫ используется для удаления начального пробела перед дробной частью.

=ТЕКСТ(12200000;"0,00E+00")

Экспоненциальное представление, например: 1,22E+07

=ТЕКСТ(1234567898;"[<=9999999]###-####;(###) ###-####")

Дополнительный формат (номер телефона), например: (123) 456-7898

=ТЕКСТ(1234;"0000000")

Добавление нулей в начале, например: 0001234

=ТЕКСТ(123456;"##0° 00' 00''")

Пользовательский формат (широта или долгота), например: 12° 34' 56''

Примечание : Функцию ТЕКСТ можно использовать для изменения форматирования, но это не единственный способ. Чтобы изменить форматирование без формулы, нажмите клавиши CTRL+1 (на компьютере Mac — +1), а затем в диалоговом окне Формат ячеек на вкладке Число выберите нужный формат.

Скачивание образцов

Предлагаем скачать книгу, в которой содержатся все примеры применения функции ТЕКСТ из этой статьи и несколько других. Вы можете воспользоваться ими или создать собственные коды форматов для функции ТЕКСТ.

Скачать примеры применения функции ТЕКСТ

Другие доступные коды форматов

Просмотреть другие доступные коды форматов можно в диалоговом окне Формат ячеек.

  1. Нажмите клавиши CTRL+1 (на компьютере Mac — +1), чтобы открыть диалоговое окно Формат ячеек.
  2. На вкладке Число выберите нужный формат.
  3. Выберите пункт (все форматы).
  4. Нужный код формата будет показан в поле Тип. В этом случае выделите всё содержимое поля Тип, кроме точки с запятой (;) и символа @. В примере ниже выделен и скопирован только код ДД.ММ.ГГГГ.
  5. Нажмите клавиши CTRL+C, чтобы скопировать код формата, а затем — кнопку Отмена, чтобы закрыть диалоговое окно Формат ячеек.
  6. Теперь осталось нажать клавиши CTRL+V, чтобы вставить код формата в функцию ТЕКСТ. Пример: =ТЕКСТ(B2;"ДД.ММ.ГГГГ"). Обязательно заключите скопированный код формата в кавычки ("код формата"), иначе в Excel появится сообщение об ошибке.
Прикрепленные файлы:
Так же в этом разделе:
 
MyTetra Share v.0.59
Яндекс индекс цитирования