firststeps.ru
www.ПЕРВЫЕ ШАГИ.ru :: Шаг 19 -Метод CreateWorkspace
4-6 минут
Описание
Создает новый объект Workspace.
Set рабочаяОбласть = CreateWorkspace(имя, пользователь, пароль, тип)
Параметры
рабочаяОбласть
Объектная переменная, представляющая создаваемый объект Workspace.
имя
Выражение или переменная типа String, содержащая уникальное имя нового объекта Workspace. Дополнительные сведения о допустимых именах объектов Workspace приведены в разделе для свойства Name.
Пользователь
Выражение или переменная типа String, определяющая владельца нового объекта Workspace. Дополнительные сведения приведены в разделе для свойства UserName.
пароль
Выражение или переменная типа String, содержащая пароль для нового объекта Workspace. Пароль может содержать до 14 любых символов кроме пустого символа ASCII 0. Дополнительные сведения о допустимых паролях приведены в разделе для свойства Password.
тип
Необязательный. Константа, определяющая тип рабочей области, как это описано в разделе "Значения":
- dbUseJet - Создание рабочей области ядра Microsoft Jet.
- dbUseODBC - Создание рабочей области ODBCDirect.
Замечания
После создания нового объекта Workspace с помощью метода CreateWorkspace открывается сеанс для новой рабочей области и становятся возможными ссылки на объект Workspace в приложении.
Объекты Workspace не являются постоянными и не сохраняются на диске. После создания нового объекта Workspace не допускается изменение значения любого из его свойств, за исключением свойства Name, которое пользователь может изменить перед добавлением объекта Workspace в семейство Workspaces.
Новый объект Workspace не обязательно добавлять в семейство перед началом работы с этим объектом. Новый объект Workspace следует добавлять в семейство только в том случае, если требуется ссылаться на этот объект через семейство Workspaces.
Аргумент тип определяет, представляет ли новый объект Workspace рабочую область ядра Microsoft Jet или рабочую область ODBCDirect. Если значением аргумента тип является константа dbUseODBC и при этом не создана ни одна рабочая область ядра Microsoft Jet, то ядро базы данных Microsoft Jet не будет загружено в память и все операции будут выполняться с источником данных ODBC, указанным в объекте Connection. Если аргумент тип опущен, источник данных для объекта Workspace будет определяться значением свойства DefaultType объекта DBEngine. Допускается сосуществование открытых рабочих областей Microsoft Jet и ODBCDirect.
Для удаления объекта Workspace из семейства Workspaces следует закрыть все открытые базы данных, а затем вызвать метод Close для объекта Workspace.
Пример
Следующая программа использует метод CreateWorkspace для создания рабочей области Microsoft Jet и рабочей области ODBCDirect. Затем печатаются списки свойств двух рабочих областей.
Sub CreateWorkspaceX()
Dim wrkODBC As Workspace
Dim wrkJet As Workspace
Dim wrkLoop As Workspace
Dim prpLoop As Property
' Создает рабочую область ODBCDirect. До создания рабочей
' области Microsoft Jet, ядро базы данных Microsoft Jet
' не будет загружено в память.
Set wrkODBC = CreateWorkspace("ODBCWorkspace", "admin", "", dbUseODBC)
Workspaces.Append wrkODBC
DefaultType = dbUseJet
' Создает безымянный объект Workspace с типом,
' указанным в свойстве DefaultType объекта DBEngine
' (dbUseJet).
Set wrkJet = CreateWorkspace("", "admin", "")
' Отображает семейство Workspaces.
Debug.Print "Объекты Workspace в семействе Workspaces:"
For Each wrkLoop In Workspaces
Debug.Print " " & wrkLoop.Name
Next wrkLoop
With wrkODBC
' Отображает семейство Properties объекта ODBCDirect.
Debug.Print "Свойства " & .Name
On Error Resume Next
For Each prpLoop In .Properties
Debug.Print " " & prpLoop.Name & " = " & prpLoop
Next prpLoop
On Error GoTo 0
End With
With wrkJet
' Отображает семейство Properties рабочей области
' Microsoft Jet.
Debug.Print "Свойства безымянной рабочей области Microsoft Jet"
On Error Resume Next
For Each prpLoop In .Properties
Debug.Print " " & prpLoop.Name & " = " & prpLoop
Next prpLoop
On Error GoTo 0
End With
wrkODBC.Close
wrkJet.Close
End Sub
