MyTetra Share
Делитесь знаниями!
Блокировка / Разблокировка папок и файлов с помощью установки прав
29.07.2019
23:36
Текстовые метки: Lock, Unlock
Раздел: Script

Блокировка / Разблокировка папок и файлов с помощью установки прав

Блокировщик может подойти как поверхностная защита для флешек от не очень умных вирусов.
Расблокировщик, например, также может помочь, когда у Вас не хватает прав для доступа к папке / файлу.

Использование:
Скачать и распаковать архив.

Unlock - расблокировщик
Lock - блокировщик

3 варианта использования:

Вариант 1) Скопировать на флешку и запустить.

Вариант 2) Перетянуть папку или файл сверху на этот батник

Вариант 3) Через контекстное меню правой кнопкой мыши по нужному файлу или папке => "Отправить".
Для этого Вам нужно предварительно скопировать файлы Lock.cmd и Unlock.cmd в папку SendTo.
SendTo Вы можете найти, нажав Пуск => в поисковую строку введите Shell:SendTo
_________________________________
Какие права устанавливаются?
В "Варианте 1" папку можно просматривать, читать и запускать файлы.
Запрещено удалять, изменять, создавать файлы и папки.

В "Вариантах 2,3" папка блокируется полностью (в т.ч. нельзя войти в нее).

Совместимость:
Система: Windows Vista и выше.
Файловая система должна быть NTFS.

Код (DOS):

@set @x=0; /*
@echo off
if "%~2"=="" (cscript.exe //nologo //e:jscript "%~fs0" "%~1"& goto :eof)
cd /d "%~dp0"
if "%~1" neq "" goto CONTEXT

:HERE
Set "Cur=%~dp0"
Set "Cur=%Cur:~0,-1%"
takeown /f "%Cur%" /r /d y
icacls "%Cur%" /deny All:(DE,WDAC,WO,AS,WD,AD,WEA,DC,WA) /T /C
icacls "%Cur%" /deny ‚бҐ:(DE,WDAC,WO,WD,AS,AD,WEA,DC,WA) /T /C
icacls "%Cur%" /grant All:(RC,S,GR,GW,GE,RD,REA,X,RA) /T /C
icacls "%Cur%" /grant ‚бҐ:(RC,S,GR,GW,GE,RD,REA,X,RA) /T /C
goto :eof

:CONTEXT
if exist "%~1\" (goto CONTEXT_FOLDER) else (goto CONTEXT_FILE)
goto :eof

:CONTEXT_FOLDER
takeown /f "%~1" /r /d y
icacls "%~1" /deny All:F /T /C
icacls "%~1" /deny ‚бҐ:F /T /C
goto :eof

:CONTEXT_FILE
takeown /f "%~1"
icacls "%~1" /deny All:F /C
icacls "%~1" /deny ‚бҐ:F /C
goto :eof

*/new ActiveXObject('Shell.Application').ShellExecute ('cmd.exe', '/c ""' + WScript.ScriptFullName + '" "' + WScript.Arguments(0) +'" "runas""','','runas',1);

Код (DOS):

@set @x=0; /*
@echo off
if "%~2"=="" (cscript.exe //nologo //e:jscript "%~fs0" "%~1"& goto :eof)
cd /d "%~dp0"
if "%~1" neq "" goto CONTEXT

:HERE
Set "Cur=%~dp0"
Set "Cur=%Cur:~0,-1%"
takeown /f "%Cur%" /r /d y
icacls "%Cur%" /grant All:f /T /C
icacls "%Cur%" /grant Все:f /T /C
goto :eof

:CONTEXT
if exist "%~1\" (goto CONTEXT_FOLDER) else (goto CONTEXT_FILE)
goto :eof

:CONTEXT_FOLDER
takeown /f "%~1" /r /d y
icacls "%~1" /grant All:f /T /C
icacls "%~1" /grant Все:f /T /C
goto :eof

:CONTEXT_FILE
takeown /f "%~1"
icacls "%~1" /grant All:f /C
icacls "%~1" /grant Все:f /C
goto :eof

*/new ActiveXObject('Shell.Application').ShellExecute ('cmd.exe', '/c ""' + WScript.ScriptFullName + '" "' + WScript.Arguments(0) +'" "runas""','','runas',1);

 

Вложения:

Прикрепленные файлы:
Так же в этом разделе:
 
MyTetra Share v.0.52
Яндекс индекс цитирования