MyTetra Share
Делитесь знаниями!
Как переименовать виртуалку в Virtualbox
03.05.2017
13:18
Текстовые метки: virtualbox, solidworks
Раздел: Обычные - Рабочие

Кстати, тем кто ставит на виртуалку (Virtualbox), как я, и получает ошибку: "Использование отдельной лицензии для SOLIDWORKS не поддерживается с этой виртуальной среде. Необходимо использовать сетевую лицензию SolidNetwork (SNL).". Поможет решение от gellmar, за что ему огромнейшее спасибо, из соседней темы :

Решение в том чтобы прописать нужные значения в DMI BIOS виртуалки.
Этот батник нужно запускать из РЕАЛЬНОЙ операционной системы (host system), например из папки с ехе виртуалбокса, и указывать первым параметром имя виртуалки:

Код:

@echo Off
setlocal EnableDelayedExpansion
echo VirtualBox Hider for SolidWorks
echo by TeAM SolidSQUAD-SSQ
if "%1"=="" goto usage
set VMNAME=%1
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/pcbios/0/Config/DmiBIOSVendor" "American Megatrends Inc"
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/pcbios/0/Config/DmiBIOSVersion" "2.1.0"
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/pcbios/0/Config/DmiSystemVendor" "ASUSTek Computer"
call:gen_random_string 9
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/pcbios/0/Config/DmiSystemSerial" "string:!rand!"
call:gen_random_string 20
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/ahci/0/Config/Port0/SerialNumber" "string:!rand!"
call:gen_random_string 8
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/ahci/0/Config/Port0/FirmwareRevision" "string:!rand!"
VBoxManage setextradata "%VMNAME%" "VBoxInternal/Devices/ahci/0/Config/Port0/ModelNumber" "SEAGATE ST3750525AS"
echo.
echo Success!
echo.
pause
goto:eof
:usage
echo Usage: %0 VM-Name
echo This script shold be started from HOST machine
echo where VM-name is a name of STOPPED VirtualBox virtual machine
echo Note: the PATH variable must contain path to VBoxManage.exe
echo like set PATH=C:\Program Files\Oracle\VirtualBox;%%PATH%%
echo.
pause
goto:eof
:gen_random_string
set lineup=0123456789ABCDEF
set RandomLength=%1
set count=0
set rand=
:loop
set /a count+=1
set /a _RND=%Random%*15/32768
set rand=!rand!!lineup:~%_RND%,1!
if !count! lss %RandomLength% goto loop
:eof

Пример использования:

Код:

set PATH=C:\Program Files\VirtualBox;%PATH%
hidevm.bat MySolidWorksVirtualBox

Запускать при ВЫКЛЮЧЕННОЙ виртуалке, после запуска виртуалки Солид ругаться не будет

------------------

Единственно, поскольку у меня хост система Ubuntu, я просто запустил команды VBoxManage поочередно, подставив название нужной виртуальной машины и использовав свою голову и руки в качестве рандомайзера.

Далее UEFI:

У меня EFI. Ключи

Код:

Key: VBoxInternal/Devices/pcbios/0/Config/DmiBIOSVendor, Value: American Megatrends Inc
Key: VBoxInternal/Devices/pcbios/0/Config/DmiBIOSVersion, Value: 2.1.0
Key: VBoxInternal/Devices/pcbios/0/Config/DmiSystemSerial, Value: 012345678
Key: VBoxInternal/Devices/pcbios/0/Config/DmiSystemVendor, Value: ASUSTek Computer

Делают систему не запускаемой. Б^*.
Ура! Я нашёл решение! Заменить везде pcbios на efi. И поехали!

 
MyTetra Share v.0.52
Яндекс индекс цитирования