MyTetra Share
Делитесь знаниями!
О, смотри-ка какое хорошее место. Дайте два!
Произвольный список выбора поля ввода в управляемой форме
28.09.2016
12:44
Текстовые метки: 1c.forms
Раздел: Программирование - 1с - forms

1. Написать обработчики событий поля: НачалоВыбора, АвтоПодбор

2. Установить значение "Не использовать" для свойства "ИсторияВыбораПриВводе" поля

Пример: Есть таблица с полями "Контрагент", "Договор". В списке выбора договора должны быть только договора из строк таблицы с определенным контрагентом.

&НаКлиенте

Процедура НачисленияДоговорАвтоПодбор(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

ДанныеВыбора = ПолучитьСписокВыбораДоговораКонтрагентаИзРеестраПлатежей(Элементы.Начисления.ТекущиеДанные.Контрагент);

КонецПроцедуры

&НаКлиенте

Процедура НачисленияДоговорНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

ОписаниеОповещения = Новый ОписаниеОповещения("ДоговорНачисленияПослеВыбора", ЭтотОбъект);

СписокВыбора = ПолучитьСписокВыбораДоговораКонтрагентаИзРеестраПлатежей(Элементы.Начисления.ТекущиеДанные.Контрагент);

ПоказатьВыборИзСписка(ОписаниеОповещения, СписокВыбора, Элемент);

КонецПроцедуры

&НаКлиенте

Процедура ДоговорНачисленияПослеВыбора(ВыбранныйЭлемент, ДополнительныеПараметры) Экспорт

Если ВыбранныйЭлемент = Неопределено Тогда

Возврат;

Иначе

Элементы.Начисления.ТекущиеДанные.Договор = ВыбранныйЭлемент.Значение;

КонецЕсли;

КонецПроцедуры

&НаСервере

Функция ПолучитьСписокВыбораДоговораКонтрагентаИзРеестраПлатежей(Контрагент)

СписокВыбора = Новый СписокЗначений;

МассивДоговоров = Новый Массив;

СтрокиКонтрагента = БизнесПроцесс.РеестрПлатежей.НайтиСтроки(Новый Структура("Контрагент", Контрагент));

Для Каждого Строка Из СтрокиКонтрагента Цикл

МассивДоговоров.Добавить(Строка.Договор);

КонецЦикла;

ОбщегоНазначенияКлиентСервер.СвернутьМассив(МассивДоговоров);

СписокВыбора.ЗагрузитьЗначения(МассивДоговоров);

Возврат СписокВыбора;

КонецФункции

← Содержание ...
 
MyTetra Share v.0.35
Яндекс индекс цитирования